This is an ASCII generic text file of the available text and (.S) - source files
from: Mouse Development Tools - Mousetext Toolkit v1.7 (4/3/84) - for use with
an Apple //e (80 Col) only.

------------
ALLOCATE.S
------------

; ALLOCATE
;
; Allocates a $1000 byte area protected from BASIC by making a call
; to BASIC.SYSTEM.  (see ProDOS tech note #9)  This area must extend 
; from $8A00 to $9A00 for toolkit.  The high byte of the address 
; returned is placed at $310 so that the calling BASIC program can 
; check it.
;
; This routine is org'ed at $300 since it is short and very temporary.
;
; See the companion progam RELEASE, which releases all memory set aside
; using this method.
;
 org $300
;
getbufr equ $BEF5 ; address of BASIC.SYSTEM's buffer allocation routine
numpgs equ $10 ; number of pages we want set aside
;
 lda #numpgs
 jsr getbufr ; allocate the buffer
 bcc continue ; if carry clear, call was successful
 lda #0 ; store an invalid # so caller detects failure
continue sta result
 rts
result equ $310 ; result must be beyond above code
---------------------------------------------------------------------------

------------
IDCHECK.S
------------

; IDCHECK
;
 org $300
;
pdosid equ $BF98 ; address of BASIC.SYSTEM's buffer allocation routine
mustbe equ $A2 ; number of pages we want set aside
mask equ $E2
;
 lda pdosid
 and #mask
 eor #mustbe
 sta result
 rts
result equ $310 ; result must be beyond above code
--------------------------------------------------------------------------

-----------
RELEASE.S
-----------

; RELEASE
;
; Releases any special buffers that BASIC has reserved by making a call to
; to BASIC.SYSTEM.  (see ProDOS tech note #9)
;
; This routine is org'ed at $300 since it is short and very temporary.
;
; See the companion progam ALLOCATE, which allocates memory for toolkit.
;
 org $300
;
freebufr equ $BEF8 ; address of BASIC.SYSTEM's buffer release routine
;
 jsr freebufr ; release any buffers set aside
 rts
---------------------------------------------------------------------------

---------------
TOOLKITDEMO.S
---------------

 sbtl .Mouse Toolkit Demo.
*
* Sample program using the Mouse Toolkit (version 1)
* See the pseudo-code example for an overview of the program structure
*
*  User runs this program by running the BASIC program START.DEMO
*  which allocates space for the toolkit, loads in the toolkit and
*  the demo program, and then runs the demo.
*
 skp 1
 org $1000
 skp 1
toolkit equ $8A00
 skp 1
 jmp progstart ; jump to program start, so this can be BRUN
 skp 1
;
; Toolkit command numbers
;
startdesktop  equ 0
stopdesktop  equ 1
setcursor  equ 2
showcursor  equ 3
hidecursor  equ 4
checkevents  equ 5
getevent  equ 6
flushevents  equ 7
setkeyevent  equ 8
initmenu  equ 9
setmenu  equ 10
menuselect  equ 11
menukey  equ 12
hilitemenu  equ 13
disablemenu  equ 14
disableitem  equ 15
checkitem  equ 16
;
; Monitor entry points
;
cout equ $FDED
crout equ $FD8E
prbyte equ $FDDA
;
; Machine ID equates
;
machid equ $FBB3
machsid equ $FBC0
;
; local variables:
;
quitflag db 0 ; high bit set = quit
;
; The program begins here!!
;
progstart equ * 
 lda #0 ; initialize quitflag
 sta quitflag
 lda machid ; get the machine's id byte
 sta mid ; store in parameter list
 lda machsid ; get machine's sub id byte
 sta msid ; store in parameter list
 skp 1
 jsr toolkit ; initialize the desktop
 db startdesktop
 dw startparms
 beq prog.cont ; continue if no error
 cmp #$04 ; check if machine is not a //e
 beq notsupported
 cmp #$06 ; check to see if no card
 beq nocard
 jmp syserror ; some other error occurred
 skp 1
notsupported equ * ; Machine is not supported (we know ProDOS is)
 lda #>notsup.str ; print the error string
 ldx #<notsup.str
 jsr prstrcr
 rts ; due to when this is called, we return to user
notsup.str str "Your machine is not supported."
 skp 1
nocard equ * ; No card was found in the machine
 lda #>nocard.str ; print the error string
 ldx #<nocard.str
 jsr prstrcr
 rts ; due to when this is called, we return to user
nocard.str str "No mouse card found."
 skp 1
prog.cont jsr toolkit
 db initmenu ; initialize menu mgr
 dw imparms 
 bne syserror ; only programming errors possible for this call
 skp 1
 jsr toolkit
 db setmenu ; set up our menus
 dw smparms
 bne syserror ; only programming errors possible for this call
 skp 1
 jsr toolkit
 db showcursor ; turn on the cursor
 dw zeroparms
 bne syserror ; only programming errors possible for this call
 skp 1
;
; Main program loop
;
loop equ *
 skp 1
;         jsr toolkit       * include this code for passive mode *
;         db checkevents    ; post any available events
;         dw zeroparms 
;         bne syserror      ; only programming errors possible for this call
 skp 1
 jsr toolkit
 db getevent ; get next event from queue
 dw evtparms 
 bne syserror ; only programming errors possible for this call
 skp 1
 lda evttype ; get the event type
 beq endcase ; (evt=0) ignore no events
 cmp #2
 beq endcase ; (evt=2) ignore button up
 cmp #1
 beq case.btn
 jsr handlekeys ; (evt=3) handle the key press
 jmp endcase
case.btn lda evtY ; (evt=1) get the Y pos of mouse
 bne case.btn.5
 jsr handlemenu ; cursor was in row 0
 jmp endcase
case.btn.5 jsr handlebutton ; handle button press not in menubar
 jmp endcase
endcase bit quitflag ; check quit flag
 bpl loop ; loop only if high bit is clear
 skp 1
 jsr toolkit
 db stopdesktop ; deactivate the toolkit
 dw zeroparms 
 bne syserror ; only programming errors possible for this call
 skp 1
 rts ; return to caller
;
; the system error routine is placed here so every one can reach it with
; a branch
;
syserror equ * ;error routine if bad status from toolkit
 pha ; save error returned by toolkit
 lda #>syse.str ; print the error string
 ldx #<syse.str
 jsr prstr
 pla ; retrieve the status
 jsr prbyte ; print the status in hex
 brk ; die horribly
syse.str str "Fatal Error: Status = $"
;
handlekeys equ * ; handle each keystroke from user here
 rts ; add code here
;
handlebutton equ * ; handle button press here
 rts ; add code here
;
handlemenu equ * ; handle the menu selection
 jsr toolkit
 db menuselect ; have toolkit get the menu selection from user
 dw msparms 
 bne syserror ; only programming errors possible for this call
 skp 1
 lda msmid ; get menu id
 bne hm.chk10
 rts ; (menuid=$00) no selection was made by the user
hm.chk10 cmp #$10
 bne hm.chk20
 lda #$FF ; (menuid=$10) set the quit flag
 sta quitflag
 jmp hm.endcase
hm.chk20 cmp #$20
 bne hm.endcase
 lda msitem ; (menuid=$20) get item #
 cmp #1
 bne hm.chk3
 jsr undolastchange ; (item#=1)
 jmp hm.endcase
hm.chk3 cmp #3
 bne hm.chk4
 jsr docut ; (item#=3)
 jmp hm.endcase
hm.chk4 cmp #4
 bne hm.chk5
 jsr docopy ; (item#=4)
 jmp hm.endcase
hm.chk5 cmp #5
 bne hm.endcase
 jsr dopaste ; (item#=5)
 jmp hm.endcase
;
hm.endcase jsr toolkit
 db hilitemenu ; unhilight title of menu selected
 dw hiliparms
 bne syserror ; only programming errors possible for this call
 skp 1
 rts
;
;
undolastchange equ * ; perform undo last change
 rts ; add code here
;
docut equ * ; preform cut
 rts ; add code here
;
docopy equ * ; preform copy
 rts ; add code here
;
dopaste equ * ; preform paste
 rts ; add code here
;
;
; prstr expects low byte of string address in A and high byte of
; string address in X
;
prstrcr equ *
 jsr prstr
 jsr crout
 rts
;
stradr equ $06 ; address in zero page for indexing with Y
tempsave dw 0 ; save area for the zero page we clobber
;
prstr equ *
 ldy stradr ; first save the zero page we are about to use
 sty tempsave
 ldy stradr+1
 sty tempsave+1
 sta stradr
 stx stradr+1
 jsr crout ; make sure we start string on a fresh line
 ldy #0 ; set up for indexing into string
 lda (stradr),y ; get the length of the string
 beq prstr.done ; if nothing in string, we are done
 iny
 tax ; put string length into x
prstr.loop lda (stradr),y ; get next char in string
 ora #$80 ; make sure high bit is on for cout
 jsr cout
 iny ; set for next char in string
 dex
 bne prstr.loop ; while more chars, loop
prstr.done lda tempsave ; restore the zero page we used
 sta stradr
 lda tempsave+1
 sta stradr+1
 rts ; return
 page
zeroparms db 0 ; parameter list of 0
 skp 1
evtparms db 3 ; parameter list for getevent
evttype db 0 ; the event type
evtx db 0 ; x pos of mouse
evty db 0 ; y pos of mouse
evtkey equ evtx ; key input by user
evtkeymod equ evty ; modifier to key input by user
 skp 1
startparms db 6 ; parameter list for start desk top
mid db 0 ; using a //e
msid db 0 ; subid byte for //e
 db $00 ; using ProDos
 db $00 ; let toolkit check slots
 db $01 ; using interupt mode
 db $01 ; using 80-columns
 skp 1
smparms db 1 ; parameter list for set menu
 dw mymenubar
 skp 1
msparms db 2 ; parameter list for menuselect
msmid db 0 ; menu id from menuselect
msitem db 0 ; item # from menuselect
 skp 1
hiliparms db 1 ; 1 parm
 db 0 ; 0 deselects all
 skp 1
imparms db 2 ; initialize menu parms
 dw msavearea ; area to use when saving menu 
 dw msavesize ; size of area
 page
mymenubar db 2 ; # of menu items
 db 0 ; reserved for future
mt1ptr db $10 ; menu id
 db 0 ; disable flag
 dw title1.str ; pointer to title1 string
 dw menu1 ; pointer to menu data
 ds 4,0 ; set aside 4 bytes
mt2ptr db $20 ; menu id
 db 0 ; disable flag
 dw title2.str ; pointer to title2 string
 dw menu2 ; pointer to menu data
 ds 4,0 ; set aside 4 bytes
title1.str str 'File'
title2.str str 'Edit'
;
menu1 db 1 ; 1 line in this menu
 ds 3,0 ; set aside 3 bytes for toolkit
 ds 4,0 ; we don't use any of the special options
 dw item1.1.str ; pointer to item string
item1.1.str str 'Quit'
;
menu2 db 5 ; 5 lines in this menu
 ds 3 ; set aside 3 bytes for toolkit
 ds 4,0 ; we aren't using any of the options
 dw item2.1.str
 db $40 ; option byte (item is filler)
 db $0 ; reserved
 db 19 ; MouseText char for solid dash
 db 0 ; don't use char 2
 dw 0 ; don't have a pointer to a string
 ds 4,0 ; we don't using any of the special options
 dw item2.2.str ; pointer to item string
 ds 4,0 ; we don't using any of the special options
 dw item2.3.str ; pointer to item string
 ds 4,0 ; we don't using any of the special options
 dw item2.4.str ; pointer to item string
item2.1.str str 'Undo Last Change'
item2.2.str str 'Cut'
item2.3.str str 'Copy'
item2.4.str str 'Paste'
;
msavesize equ 200 ; amount of area to set aside for temp screen save
msavearea ds msavesize ; temporary screen save area for menuselect
---------------------------------------------------------------------------
--------------------------------
MAKETOOLKIT  (A TEXT FILE ONLY)
--------------------------------

new
xload /source/start.demo
xsave /toolkit/start.demo
new
prefix /source
asm toolkit,/toolkit/toolkit.obj
new
prefix /toolkit
load /source/release
save release
load /source/allocate
save allocate
load /source/idcheck
save idcheck
load /source/toolkitdemo
save toolkitdemo
new
asm release
new
asm allocate
new
asm idcheck
new
asm toolkitdemo
exit basic.system
-------------------

And, as a bonus within the archive and on the disk you will also find;
EDASM.ASM, EDASM.ED and EDASM.SWAP (ProDOS Editor-Assembler 1.0). Look
for Mouse Developers Tools - Mouse Toolkit v2.0 in the October issue.

-END OF FILE-